В архиве TestVK.zip находится информационная база с примером использования 
весовой компоненты для 1С 7.7

файл весовой компоненты находится в архиве по следующему пути:
\TestVK\DLL\GetWeight.dll

Исходный код по инициализации и использованию весовой компоненты:
--------------------------------------------------------------------

//+++++++++++++++ Глобальный модуль ++++++++++++++++++++++++++++++++:

перем ВесовойИндикатор1 Экспорт;
перем ВесовойИндикатор2 Экспорт;

Процедура ПриНачалеРаботыСистемы()                   
  имяф = КаталогИБ()+"DLL\GetWeight.dll";     
  
  Если ЗагрузитьВнешнююКомпоненту(имяф) = 0 
  Тогда
    Сообщить("Ошибка при загрузке внешней компоненты " + имяф);
    Сообщить(ОписаниеОшибки());
  КонецЕсли;	

  Попытка
    ВесовойИндикатор1 = СоздатьОбъект("AddIn.GetWeight"); 
    ВесовойИндикатор2 = СоздатьОбъект("AddIn.GetWeight"); 
  Исключение
    Сообщить("Не удается создать объект AddIn.GetWeight");
    Сообщить(ОписаниеОшибки());
  КонецПопытки;
	
  ОткрытьФорму("Отчет.Проверка");
КонецПроцедуры 

//+++++++++++++++ Форма-Отчёт.Проверка +++++++++++++++++++++++++++++:


Процедура ПриОткрытии()
  Попытка                                                                   
    Сообщить("Открываем соединение с сервером GetWeight.");
    
    // необходимо указать ip адрес компьютера где установлент Cервер GetWeight
    // и порт который Cервер GetWeight открыл для подключыения

    Если ВесовойИндикатор1.Подключиться("localhost", 8810) = 0  //английский вариант: .Connect("localhost", 8810)
    Тогда
      Сообщить("Индикатор1 не может подключиться к серверу GetWeight.");
    КонецЕсли;        

    Если ВесовойИндикатор2.Подключиться("localhost", 8815) = 0 
    Тогда
      Сообщить("Индикатор2 не может подключиться к серверу GetWeight.");
    КонецЕсли;  
	
    Форма.ОбработкаОжидания("ОтобразитьВес", 1);
  Исключение
    Сообщить(ОписаниеОшибки());
  КонецПопытки;
КонецПроцедуры

Функция ПолучитьВес(ВесовойИндикатор) 
  Попытка
    // 1. проверяем соединение с сервером GetWeight (1 - соединение установлено, 0 - соединение не установлено)
    Если ВесовойИндикатор.СерверПодключен = 0//английский вариант: .ServerConnected
    Тогда 
      Возврат("Нет связи с Сервером");
    КонецЕсли;  
	  
    // 2. проверяем получает ли сервер GetWeight значения веса от индикатора (1 - получает, 0 - не получает)
    Если ВесовойИндикатор.ИндикаторПодключен = 0//английский вариант: .IndicatorConnected
    Тогда 
      Возврат("Нет связи с Индикатором");
    КонецЕсли;  
	  
    // 3. проверяем есть ли движение на весовой платформе (1 - есть движение, 0 - нет движения)
    Если ВесовойИндикатор.ДвижениеНаПлатформе <> 0 //английский вариант: .Motion
    Тогда 
      Возврат("Движение на платформе");
    КонецЕсли;  
	
    // 4. получаем вес в киллограммах 
    Возврат(ВесовойИндикатор.Вес);  //английский вариант: .Weight
  Исключение
    Сообщить(ОписаниеОшибки());
    Возврат("Ошибка");
  КонецПопытки; 
КонецФункции

Процедура ОтобразитьВес()
  Форма.Индикатор1.Заголовок(ПолучитьВес(ВесовойИндикатор1));	
  Форма.Индикатор2.Заголовок(ПолучитьВес(ВесовойИндикатор2));	
КонецПроцедуры

Процедура ф_ПолучитьВес1()  
  Сообщить("Индикатор №1: " + ПолучитьВес(ВесовойИндикатор1));    
КонецПроцедуры

Процедура ф_ПолучитьВес2()  
  Сообщить("Индикатор №2: " + ПолучитьВес(ВесовойИндикатор2));    
КонецПроцедуры

Процедура ПриЗакрытии()
  Попытка
    Сообщить("Закрываем соединение с сервером GetWeight.");
    ВесовойИндикатор1.Отключиться();  //английский вариант: .Disconnect();
    ВесовойИндикатор2.Отключиться();  //английский вариант: .Disconnect();
  Исключение
    Сообщить(ОписаниеОшибки());
  КонецПопытки; 
КонецПроцедуры
